class
	SETTER_SHORTHAND_FEATURE

inherit
	CLASS_FEATURE
		rename
			make as make_feature
		end

create
	make

feature {NONE} -- Initialization

	make (line, a_attribute_name: ZSTRING; a_get_attribute_type: like get_attribute_type)
		do
			make_feature (line)
			attribute_name := a_attribute_name; get_attribute_type := a_get_attribute_type
		end

feature -- Element change

	expand_shorthand
		-- expand setter shorthand notation
		do
			Atttribute_setter_template.put (Var.name, attribute_name)
			if attached get_attribute_type (attribute_name) as type then
				if type.is_empty then
					Atttribute_setter_template.put (Var.type, Like_prefix + attribute_name)
				else
					Atttribute_setter_template.put (Var.type, type)
				end
			end
			lines.wipe_out
			if attached Atttribute_setter_template.substituted.lines as setter_lines then
				setter_lines.indent (1)
				lines.append (setter_lines)
			end
			name := Set_prefix + attribute_name
		end

feature {NONE} -- Internal attributes

	attribute_name: ZSTRING

	get_attribute_type: FUNCTION [ZSTRING, ZSTRING]

feature {NONE} -- Constants

	Atttribute_setter_template: EL_ZSTRING_TEMPLATE
		local
			str: STRING
		once
			str := "[
				set_$name (a_$name: $type)
					do
						$name := a_$name
					end
			]"
			str.append_character ('%N')
			create Result.make (str)
		end

feature {NONE} -- Constants

	Set_prefix: ZSTRING
		once
			Result := "set_"
		end

	Var: TUPLE [name, type: IMMUTABLE_STRING_8]
		once
			create Result
			Tuple.fill_immutable (Result, "name, type")
		end
end