class
	PYXIS_ECF_CONVERTER

inherit
	EL_APPLICATION_COMMAND

	EL_PYXIS_TO_XML_CONVERTER
		redefine
			check_output_xml, description, new_output_path, new_xml_generator
		end

create
	make

feature -- Constants

	Description: STRING = "Convert Pyxis format Eiffel project configuration to `.ecf' XML file"

feature {NONE} -- Implementation

	check_output_xml
		local
			ecf_xdoc: EL_XML_DOC_CONTEXT
		do
			create ecf_xdoc.make_from_file (output_path)
			if ecf_xdoc.parse_failed then
				if attached ecf_xdoc.last_exception as exception then
					exception.put_error (lio)
				end
			else
				lio.put_labeled_string ("No errors detected in", output_path.base)
				lio.put_new_line
			end
		end

	new_output_path: FILE_PATH
		do
			Result := if source_path.has_extension (Pecf) then source_path.with_new_extension ("ecf") else Precursor end
		end

	new_xml_generator: EL_PYXIS_XML_TEXT_GENERATOR
		do
			if source_path.has_extension (Pecf) then
				create {ECF_XML_GENERATOR} Result.make
			else
				create Result.make
			end
		end

feature {NONE} -- Constants

	Pecf: STRING = "pecf"
end