deferred class
	EL_X509_CERTIFICATE_READER_COMMAND_I

inherit
	EL_FILE_PATH_OPERAND_COMMAND_I
		rename
			file_path as crt_file_path,
			set_file_path as set_crt_file_path
		export
			{NONE} all
			{ANY} execute
		undefine
			do_command, is_captured, new_command_parts
		redefine
			make_default
		end

	EL_CAPTURED_OS_COMMAND_I
		undefine
			getter_function_table, make_default, new_transient_fields
		end

	EL_PLAIN_TEXT_LINE_STATE_MACHINE
		rename
			make as make_machine,
			do_with_lines as parse_lines
		end

feature {NONE} -- Initialization

	make_default
			--
		do
			make_machine
			create data_table.make (7)
			create name; Tuple.fill (name, name_list)
			Precursor {EL_FILE_PATH_OPERAND_COMMAND_I}
			left_adjusted := True
		end

feature -- Access

	data_table: EL_HASH_TABLE [STRING, STRING]
		-- table of hex-strings by field

	rsa_key: EL_REFLECTIVE_RSA_KEY
		require
			enough_fields: data_table.count = data_field_count
		deferred
		ensure
			matches_key_size: key_size = Result.modulus.bits
		end

feature -- Measurement

	data_field_count: INTEGER
		do
			Result := data_fields.count - 1
		end

	key_size: INTEGER
		-- key size in bits

feature {NONE} -- State handlers

	append_field_data (line: ZSTRING; index: INTEGER)
		local
			value: ZSTRING; hex_string: STRING
		do
			if line.starts_with (data_fields.last) then
				-- Remove colons from hex strings
				across data_table as table loop
					hex_string := table.item
					if hex_string.starts_with (once "00:") then
						hex_string.remove_head (3)
					end
					hex_string.prune_all (':')
				end
				state := final
			elseif line.starts_with (data_fields [index]) then
				state := agent append_field_data (?, index + 1)
				if data_fields [index] ~ Name.exponent then
					value := line.substring_between (Bracket.left, Bracket.right, 1)
					value.remove_head (2)
					data_table.put (value, data_fields [index])
				else
					data_table.put (create {STRING}.make_empty, data_fields [index])
				end
			else
				line.append_to_string_8 (data_table.found_item)
			end
		end

	find_public_key (line: ZSTRING)
		local
			value: ZSTRING
		do
			if line.starts_with (Name.key_size) then
				value := line.substring_between (Bracket.left, Bracket.right, 1)
				value.remove_tail (4)
				key_size := value.to_integer
				state := agent append_field_data (?, 1)
			end
		end

feature {NONE} -- Implementation

	data_fields: EL_ZSTRING_LIST
		deferred
		end

	field: EL_COLON_FIELD_ROUTINES
		do
		end

	name_list: STRING
		deferred
		end

feature {NONE} -- Internal attributes

	name: TUPLE [exponent, key_size, serial_number: ZSTRING]

feature {NONE} -- Constants

	Bracket: TUPLE [left, right: ZSTRING]
		once
			create Result
			Tuple.fill (Result, "(, )")
		end

end