class
	EL_MENU_DESKTOP_ENVIRONMENT_IMP

inherit
	EL_MENU_DESKTOP_ENVIRONMENT_I
		undefine
			command_path
		redefine
			make
		end

	EL_DESKTOP_ENVIRONMENT_IMP
		undefine
			make, application_command
		end

	EL_MS_WINDOWS_DIRECTORIES

	EL_MODULE_DEFERRED_LOCALE

create
	make

feature {NONE} -- Initialization

	make (installable: EL_INSTALLABLE_APPLICATION)
			--
		do
			Precursor {EL_MENU_DESKTOP_ENVIRONMENT_I} (installable)
			application_menu_dir := Start_menu_programs_dir #+ submenu_path_steps
			shortcut_path := application_menu_dir + shortcut_name
		end

feature -- Access

	shortcut_path: FILE_PATH

feature -- Status query

	launcher_exists: BOOLEAN
			--
		do
			Result := shortcut_path.exists
		end

feature -- Basic operations

	add_menu_entry
			--
		local
			shortcut: COM_SHELL_LINK
		do
			if not application_menu_dir.exists then
				File_system.make_directory (application_menu_dir)
			end
			create shortcut.make
			shortcut.set_elevated (Has_elevated)
			shortcut.set_arguments (command_args)
			shortcut.set_target_path (command_path)
			shortcut.set_icon ([launcher.windows_icon_path, 1])
			shortcut.set_description (Locale * launcher.comment)

			shortcut.save (shortcut_path)
			if has_desktop_launcher then
				shortcut.save (desktop_shortcut_path)
			end
		end

	remove_menu_entry
			--
		do
			across << shortcut_path, desktop_shortcut_path >> as l_path loop
				if l_path.item.exists then
					File_system.remove_file (l_path.item)
				end
			end
			File_system.delete_empty_branch (application_menu_dir)
		end

feature -- Element change

	set_shortcut_path (a_shortcut_path: FILE_PATH)
		do
			shortcut_path := a_shortcut_path
		end

feature {NONE} -- Implementation

	desktop_shortcut_path: FILE_PATH
		do
			Result := Desktop_common + shortcut_name
		end

	shortcut_name: ZSTRING
		do
			Result := launcher.name + ".lnk"
		end

	submenu_path_steps: EL_PATH_STEPS
		do
			create Result.make_steps (submenu_path.count)
			across submenu_path as submenu loop
				Result.extend (submenu.item.name)
			end
		end

feature {NONE} -- Internal attributes

	application_menu_dir: DIR_PATH

feature {NONE} -- Constants

	Has_elevated: BOOLEAN
		-- `True' if saved shortcut has ability to launch with elevated privileges
		once
			Result := False
		end

end