deferred class
	EL_PYXIS_TREE_COMPILER

inherit
	EL_COMMAND

	EL_MODULE_EXCEPTION; EL_MODULE_FILE_SYSTEM; EL_MODULE_LIO; EL_MODULE_USER_INPUT

	EL_FILE_OPEN_ROUTINES

feature {NONE} -- Initialization

	make (a_manifest_path: FILE_PATH; a_source_tree_path: DIR_PATH)
		do
			make_default
			manifest_path := a_manifest_path
			source_tree_path := a_source_tree_path
		end

	make_default
		do
			create source_tree_path
		end

feature -- Status query

	is_updated: BOOLEAN

feature -- Basic operations

	execute
			--
		do
			if source_changed then
				compile
				is_updated := True
			else
				lio.put_line ("Source has not changed")
				is_updated := False
			end
		end

feature {NONE} -- Deferred

	compile
		deferred
		end

	output_modification_time: INTEGER
		deferred
		end

feature {NONE} -- Implementation

	new_manifest: EL_PYXIS_FILE_MANIFEST
		do
			create Result.make (manifest_path, Pyx_extension)
			if is_lio_enabled then
				from until not Result.has_errors loop
					lio.put_line ("FIX PATH ERRORS")
					Result.display_bad_paths (lio)
					lio.put_new_line
					if User_input.approved_action_y_n ("Retry") then
						create Result.make (manifest_path, Pyx_extension)
					end
				end
			else
				if Result.has_errors then
					Exception.raise_developer ("Manifest %S has path errors", [manifest_path.base])
				end
			end
		end

	new_merged_lines: EL_MERGED_PYXIS_LINE_LIST
		do
			create Result.make (new_source_path_list)
		end

	new_source_path_list: EL_FILE_PATH_LIST
		do
			if source_tree_path.exists then
				Result := File_system.files_with_extension (source_tree_path, Pyx_extension, True)

			elseif manifest_path.exists then
				Result := new_manifest.new_file_list
			else
				create Result.make (0)
			end
		end

	new_relative_source_path_list: EL_FILE_PATH_LIST
		do
			if source_tree_path.exists and then
				attached File_system.files_with_extension (source_tree_path, Pyx_extension, True) as path_list
			then
				Result := path_list.relative_list (source_tree_path)

			elseif manifest_path.exists and then attached new_manifest.location_file_map_list as list then
				create Result.make (list.count)
				from list.start until list.after loop
					Result.extend (list.item_value.relative_path (list.item_key))
					list.forth
				end
			else
				create Result.make (0)
			end
		end

	source_changed: BOOLEAN
		local
			modification_time: INTEGER
		do
			modification_time := output_modification_time
			Result := across new_source_path_list as file_path some
				file_path.item.modification_time > modification_time
			end
		end

feature {NONE} -- Internal attributes

	manifest_path: FILE_PATH

	source_tree_path: DIR_PATH

feature {NONE} -- Constants

	Pyx_extension: STRING = "pyx"

end