deferred class
	EL_BUILDABLE_FROM_NODE_SCAN

inherit
	EL_CREATEABLE_FROM_NODE_SCAN
		export
			{NONE} all
			{ANY} build_from_stream, build_from_string, build_from_lines, build_from_file,
					set_parser_type, generator
		end

	EL_EIF_OBJ_BUILDER_CONTEXT
		export
			{NONE} all
			{EL_DOCUMENT_EIFFEL_OBJECT_BUILDER, EL_EIF_OBJ_ROOT_BUILDER_CONTEXT} set_node
		redefine
			make_default, new_building_actions
		end

	EL_MODULE_NAMING

feature {EL_EIF_OBJ_ROOT_BUILDER_CONTEXT} -- Initialization

	make_default
			--
		do
			create xml_name_space.make_empty
			Precursor {EL_EIF_OBJ_BUILDER_CONTEXT}
			PI_building_actions := PI_building_actions_by_type.item (Current)
		end

feature -- Access

	xml_name_space: STRING note option: transient attribute end

feature {NONE} -- Element change

	set_xml_name_space_from_node
			--
		do
			xml_name_space := node.to_string_8
		end

feature {EL_DOCUMENT_EIFFEL_OBJECT_BUILDER, EL_EIF_OBJ_ROOT_BUILDER_CONTEXT, EL_BUILDABLE_FROM_NODE_SCAN} -- Factory

	new_building_actions: like building_actions
			--
		do
			Result := Precursor
			Result.put (agent set_xml_name_space_from_node, once "@xmlns")
		end

	new_pi_building_actions: like building_actions
			--
		local
			action_table: like PI_building_action_table
		do
			action_table := PI_building_action_table
			create Result.make (action_table.count)
			Result.compare_objects
			from action_table.start until action_table.after loop
				Result.extend (action_table.item_for_iteration , action_table.key_for_iteration.as_string_32)
				action_table.forth
			end
		end

	new_node_source: EL_DOCUMENT_EIFFEL_OBJECT_BUILDER
			--
		do
			create Result.make (parse_event_source_type)
		end

feature {EL_EIF_OBJ_BUILDER_CONTEXT, EL_DOCUMENT_NODE_SCAN_SOURCE} -- Implementation

	class_prefix_word_count: INTEGER
		-- number of words used as prefix for class name
		do
			inspect generator.index_of ('_', 1)
			 	when 2, 3 then
			 		Result := 1
			 else
			 	Result := 0
			 end
		end

	default_root_node_name: STRING
		-- `generator.as_lower' with `class_prefix_word_count' words pruned from start
		do
			Result := Naming.class_as_snake_lower (Current, class_prefix_word_count, 0)
		end

	PI_building_action_table: EL_PROCEDURE_TABLE [STRING]
		-- building actions assigned to top level processing instructions
		-- i.e. the same level as the root element
		do
			create Result
		end

	root_node_name: STRING
			--
		deferred
		end

feature {EL_EIF_OBJ_BUILDER_CONTEXT, EL_DOCUMENT_NODE_SCAN_SOURCE} -- Internal attributes

	PI_building_actions: like building_actions note option: transient attribute end

feature {NONE} -- Constants

	PI_building_actions_by_type: EL_FUNCTION_RESULT_TABLE [EL_BUILDABLE_FROM_NODE_SCAN, EL_PROCEDURE_TABLE [STRING]]
			--
		once
			create Result.make (11, agent {EL_BUILDABLE_FROM_NODE_SCAN}.new_pi_building_actions)
		end

note
	descendants: "[
			EL_BUILDABLE_FROM_NODE_SCAN*
				${EL_SMART_BUILDABLE_FROM_NODE_SCAN}
					${EL_SMART_XML_TO_EIFFEL_OBJECT_BUILDER}
				${EL_BUILDABLE_FROM_XML}*
					${BIOINFORMATIC_COMMANDS}
					${MATRIX_CALCULATOR}
				${EL_FILE_PERSISTENT_BUILDABLE_FROM_NODE_SCAN}*
					${EL_FILE_PERSISTENT_BUILDABLE_FROM_XML}*
						${WEB_FORM}
						${SMIL_PRESENTATION}
				${EL_BUILDABLE_FROM_PYXIS}*
					${EL_TRANSLATION_TABLE}

	]"
end