class EL_QUERY_CONDITION

(source code)

Client examples: CONTAINER_STRUCTURE_TEST_SET ;  EXPORT_MUSIC_TO_DEVICE_TASK_TEST_SET ;  EXPORT_TO_DEVICE_TASK ;  RBOX_DATABASE ;  SONG_IN_PLAYLIST_QUERY_CONDITION ;  STORAGE_DEVICE

description

Abstract query condition for use with {EL_CONTAINER_STRUCTURE}.query and related functions

tests

Class CONTAINER_STRUCTURE_TEST_SET

note
	description: "[
		Abstract query condition for use with ${EL_CONTAINER_STRUCTURE}.query and related functions
	]"
	tests: "Class ${CONTAINER_STRUCTURE_TEST_SET}"

	author: "Finnian Reilly"
	copyright: "Copyright (c) 2001-2022 Finnian Reilly"
	contact: "finnian at eiffel hyphen loop dot com"

	license: "MIT license (See: en.wikipedia.org/wiki/MIT_License)"
	date: "2025-11-18 9:08:41 GMT (Tuesday 18th November 2025)"
	revision: "14"


deferred class
	EL_QUERY_CONDITION [G]

feature -- Status query

	met (item: G): BOOLEAN
		-- True if condition is met for `item`
		deferred
		end

feature -- Addition

	conjuncted alias "and" (right: EL_QUERY_CONDITION [G]): EL_AND_QUERY_CONDITION [G]
		do
			create Result.make (Current, right)
		end

	disjuncted alias "or" (right: EL_QUERY_CONDITION [G]): EL_OR_QUERY_CONDITION [G]
		do
			create Result.make (Current, right)
		end

	negated alias "not": EL_NOT_QUERY_CONDITION [G]
		do
			create Result.make (Current)
		end

end